Theory Seq_compo_cpo

           (*-------------------------------------------*
            |                CSP-Prover                 |
            |               February 2005               |
            |        Yoshinao Isobe (AIST JAPAN)        |
            *-------------------------------------------*)

theory Seq_compo_cpo = CSP_proc + Domain_SF_prod_cpo:

(*  The following simplification rules are deleted in this theory file *)
(*  because they unexpectly rewrite UnionT and InterT.                 *)
(*                  disj_not1: (~ P | Q) = (P --> Q)                   *)

declare disj_not1 [simp del]

(*  The following simplification is sometimes unexpected.              *)
(*                                                                     *)
(*             not_None_eq: (x ~= None) = (EX y. x = Some y)           *)

declare not_None_eq [simp del]

(*  The following simplification rules are deleted in this theory file *)
(*  because they unexpectly rewrite UnionT and InterT.                 *)
(*                  Union (B ` A) = (UN x:A. B x)                      *)
(*                  Inter (B ` A) = (INT x:A. B x)                     *)
(*                  disj_not1: (~ P | Q) = (P --> Q)                   *)

declare Union_image_eq [simp del]
declare Inter_image_eq [simp del]

(*****************************************************************

         1. [[P ;; Q]]T : continuous
         2. [[P ;; Q]]F : continuous
         3. 
         4. 

 *****************************************************************)

(*** Seq_compo_evalT_continuous ***)

lemma Seq_compo_evalT_continuous:
 "[| continuous [[P]]T ; continuous [[Q]]T |]
  ==> continuous [[P ;; Q]]T"
apply (simp add: continuous_iff)
apply (intro allI impI)
apply (drule_tac x="X" in spec, simp)
apply (drule_tac x="X" in spec, simp)
apply (elim conjE exE)

apply (subgoal_tac "xa = x")
apply (rule_tac x="x" in exI, simp)

apply (subgoal_tac "X ~= {}")
apply (simp add: isLUB_UnionT)
apply (rule eq_iffI)

(* <= *)
 apply (rule)
 apply (simp add: memT_UnionT)
 apply (simp only: Seq_compo_mem)
 apply (simp add: memT_UnionT)
 apply (elim bexE exE conjE disjE)
 apply (rule_tac x="xb" in bexI)
 apply (fast)
 apply (simp)

 apply (simp add: directed_def)
 apply (drule_tac x="xb" in spec)
 apply (drule_tac x="xc" in spec)
 apply (simp, elim conjE exE)
 apply (rule_tac x="z" in bexI)
 apply (rule disjI2)
 apply (rule_tac x="s" in exI)
 apply (rule_tac x="ta" in exI)
 apply (simp)
 apply (rule conjI)
 apply (rule memT_subsetT, simp)
 apply (simp add: evalT_mono)
 apply (rotate_tac -4)
 apply (rule memT_subsetT, simp)
 apply (simp add: evalT_mono)
 apply (simp)

(* => *)
 apply (rule)
 apply (simp add: memT_UnionT)
 apply (simp only: Seq_compo_mem)
 apply (simp add: memT_UnionT)
 apply (fast)

apply (simp add: directed_def)
by (simp add: LUB_unique)

(*** Seq_compo_evalF_continuous ***)

lemma Seq_compo_evalF_continuous:
 "[| continuous [[P]]F ; continuous [[Q]]F ;
     continuous [[P]]T |]
  ==> continuous [[P ;; Q]]F"
apply (simp add: continuous_iff)
apply (intro allI impI)
apply (drule_tac x="X" in spec, simp)
apply (drule_tac x="X" in spec, simp)
apply (drule_tac x="X" in spec, simp)
apply (elim conjE exE)

apply (subgoal_tac "xa = x")
apply (subgoal_tac "xb = x")
apply (rule_tac x="x" in exI, simp)

apply (subgoal_tac "X ~= {}")
apply (simp add: isLUB_UnionF)
apply (simp add: isLUB_UnionT)
apply (rule eq_iffI)

(* <= *)
 apply (rule)
 apply (simp add: memF_UnionF)
 apply (simp add: Seq_compo_mem)
 apply (simp add: memF_UnionF)
 apply (simp add: memT_UnionT)
 apply (elim conjE bexE disjE)

 (* 1 *)
  apply (fast)

 (* 2 *)
  apply (elim conjE bexE exE)
  apply (simp add: directed_def)
  apply (drule_tac x="xc" in spec)
  apply (drule_tac x="xd" in spec)
  apply (simp, elim conjE exE)
  apply (rule_tac x="z" in bexI)
  apply (rule disjI2)
  apply (rule_tac x="sa" in exI)
  apply (rule_tac x="t" in exI)
  apply (simp)

  apply (rule conjI)
  apply (rule memT_subsetT, simp)
  apply (simp add: evalT_mono)
  apply (rotate_tac -4)
  apply (rule memF_subsetF, simp)
  apply (simp add: evalF_mono)
  apply (simp)

(* => *)
 apply (rule)
 apply (simp add: memF_UnionF)
 apply (simp add: Seq_compo_mem)
 apply (simp add: memF_UnionF)
 apply (simp add: memT_UnionT)
 apply (fast)

apply (simp add: directed_def)
by (simp_all add: LUB_unique)

(****************** to add them again ******************)

declare Union_image_eq [simp]
declare Inter_image_eq [simp]
declare disj_not1      [simp]
declare not_None_eq    [simp]

end